Как использовать базу данных SQLite из QML? [Дубликат]

Следуйте этому руководству: https://wiki.dolphin-emu.org/index.php? title=How_to_use_the_Official_GameCube_Controller_Adapter_for_Wii_U_in_Dolphin

конкретные инструкции Linux может быть найден здесь: https://wiki.dolphin-emu.org/index.php? title=How_to_use_the_Official_GameCube_Controller_Adapter_for_Wii_U_in_Dolphin#Linux

Также отмечает, что адаптер должен будет быть установлен на режим Wii U заранее даже при использовании его на ПК.

3
задан 14.04.2020, 11:13

2 ответа

Я попробовал пример SQLite с QML и C ++. Вы можете загрузить данные с кодом C ++ и затем отправить их в код QML

0
ответ дан 14.04.2020, 11:14
  • 1
    Можно ли совместно использовать тот пример? Я хочу создать приложение для касания человечности (планшет или телефон) использующий главным образом код QML, поскольку мои навыки C++ не усовершенствованный – Arjang 14.04.2020, 11:14

Вы можете использовать API автономного хранилища SQLite непосредственно из Qml, используя Javascript:

import QtQuick.LocalStorage 2.0

. Если вы хотите подробные примеры, я бы предложил рассмотрим источник некоторых из Ubuntu Touch Core-Apps . Я знаю, что по крайней мере приложения погоды, часов и RSS-ридера все используют это. А пока вот простой пример:

import QtQuick.LocalStorage 2.0
import QtQuick 2.0
import Ubuntu.Components 0.1

MainView {
    id: root
    // Note: applicationName sets the storage path
    applicationName: "com.ubuntu.developer.andrewsomething.example-app"

    width: units.gu(50)
    height: units.gu(75)

    property var db: null

    function openDB() {
        if(db !== null) return;

        // db = LocalStorage.openDatabaseSync(identifier, version, description, estimated_size, callback(db))
        db = LocalStorage.openDatabaseSync("example-app", "0.1", "Simple example app", 100000);

        try {
            db.transaction(function(tx){
                tx.executeSql('CREATE TABLE IF NOT EXISTS settings(key TEXT UNIQUE, value TEXT)');
                var table  = tx.executeSql("SELECT * FROM settings");
                // Seed the table with default values
                if (table.rows.length == 0) {
                    tx.executeSql('INSERT INTO settings VALUES(?, ?)', ["distro", "Ubuntu"]);
                    tx.executeSql('INSERT INTO settings VALUES(?, ?)', ["foo", "Bar"]);
                    console.log('Settings table added');
                };
            });
        } catch (err) {
            console.log("Error creating table in database: " + err);
        };
    }


    function saveSetting(key, value) {
        openDB();
        db.transaction( function(tx){
            tx.executeSql('INSERT OR REPLACE INTO settings VALUES(?, ?)', [key, value]);
        });
    }

    function getSetting(key) {
        openDB();
        var res = "";
        db.transaction(function(tx) {
            var rs = tx.executeSql('SELECT value FROM settings WHERE key=?;', [key]);
            res = rs.rows.item(0).value;
        });
        return res;
    }

    Page {
        id: app
        title: i18n.tr("Settings")

        Column {
            anchors.fill: parent
            anchors.margins: units.gu(5)
            spacing: units.gu(2)

            OptionSelector {
                id: distroToggle
                text: i18n.tr("Favorite Distro")
                model: [i18n.tr("Ubuntu"), i18n.tr("Debian")]
            }

            OptionSelector {
                id: fooToggle
                text: i18n.tr("Foo")
                model: [i18n.tr("Bar"), i18n.tr("Baz")]
            }

            Button {
                text: i18n.tr("Save settings")
                onClicked: {
                    var distro = (distroToggle.selectedIndex === 0) ? "Ubuntu" : "Debian";
                    console.log("Saved " + distro);
                    saveSetting("distro", distro);

                    var foo = (fooToggle.selectedIndex === 0) ? "Bar" : "Baz";
                    console.log("Saved " + foo);
                    saveSetting("foo", foo);
                }
            }
        }

        Component.onCompleted: {
            var distro = getSetting('distro');
            distroToggle.selectedIndex = (distro === "Debian") ? 1 : 0;
            var foo = getSetting('foo');
            fooToggle.selectedIndex = (foo === "Baz") ? 1 : 0;
        }
    }
}

Он устанавливает базу данных и некоторые функции для получения и сохранения пар ключ / значение. Затем он предоставляет интерфейс, используя компоненты Ubuntu OptionSelector.

settings dialog

7
ответ дан 14.04.2020, 11:15

Теги

Похожие вопросы